blob: 68d49892c2f6a4e2f43eb6055fe5f2bc2ebefd23 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
#!/usr/bin/env fish
# load environment
source (dirname (status --current-filename))/env
set -l gitCommand
set -l repoDir
# redirect stdout/stderr to file, no information to potential attacker
begin
# check given git command
# basic form is <git-command> '<path-to-repo>'
set -l currentUser (whoami)
set -l matcher (string match -r -g $_GIT_VALIDATION_REGEX -- "$argv")
if test (count $matcher) -ne 2
echo "$(date -Is): DENY bad_format user=$currentUser ip=$SSH_CONNECTION argv=$argv"
exit 1
end
# extract variables from git command
set gitCommand $matcher[1]
set -l repo $matcher[2]
# adjust repo path to /srv/repos
set repoDir /(string join -n '/' srv repos (string split '/' $repo))
# check if realPath is in jail under /srv/repos
set -l realPath (realpath $repoDir)
if not string match -r -q -- "/srv/repos/.*" "$realPath"
echo "$(date -Is): DENY jail_escape user=$currentUser ip=$SSH_CONNECTION realPath=$realPath argv=$argv"
exit 2
end
# check for permissions
if not cat $_REPO_PERMISSIONS_FILE | grep -q -E "^$repoDir:$currentUser\$"
echo "$(date -Is): DENY no_permissions user=$currentUser ip=$SSH_CONNECTION argv=$argv"
exit 3
end
# info logging
echo "$(date -Is): ALLOW ok user=$currentUser ip=$SSH_CONNECTION argv=$argv"
end &>>$_LOG
# execute parsed git command
/usr/bin/sudo -u git /usr/bin/git-shell -c "$gitCommand '$repoDir'"
|
